[3] ESP32 - Arduino - Przycisk dotykowy

W tym poście chciałbym opisać sposób wykonania przycisku dotykowego na ESP32.

[Źródło: http://paulobrien.co.nz/2017/03/16/esp32-programming-with-arduino-on-windows/]

ESP32 zawiera 10 pinów, które można przygotować jako czujnik pojemnościowy.

• TOUCH0 - GPIO4
• TOUCH1 - GPIO0
• TOUCH2 - GPIO2
• TOUCH3 - GPIO15
• TOUCH4 - GPIO13
• TOUCH5 - GPIO12
• TOUCH6 - GPIO14
• TOUCH7 - GPIO27
• TOUCH8 - GPIO33
• TOUCH9 - GPIO32

W celu odczytu danych z pinu pojemnościowego wykorzystuje się jedną funkcję w Arduino IDE tj. touchRead(PIN_NUMBER)

Funkcja opisana w bibliotece wygląda następująco:

1. extern uint16_t touchRead(uint8_t pin) __attribute__ ((weak, alias("__touchRead")));
3. uint16_t __touchRead(uint8_t pin)
4. {
5.     int8_t pad = digitalPinToTouchChannel(pin);
6.     if(pad < 0){
7.         return 0;
8.     }
9.     pinMode(pin, ANALOG);
10.     __touchInit();
11.     uint32_t v0 = READ_PERI_REG(SENS_SAR_TOUCH_ENABLE_REG);
12.     //Disable Intr & enable touch pad
13.     WRITE_PERI_REG(SENS_SAR_TOUCH_ENABLE_REG,
14.             (v0 & ~((1 << (pad + SENS_TOUCH_PAD_OUTEN2_S)) | (1 << (pad + SENS_TOUCH_PAD_OUTEN1_S))))
15.             | (1 << (pad + SENS_TOUCH_PAD_WORKEN_S)));
17.     SET_PERI_REG_MASK(SENS_SAR_TOUCH_ENABLE_REG, (1 << (pad + SENS_TOUCH_PAD_WORKEN_S)));
18.     uint32_t rtc_tio_reg = RTC_IO_TOUCH_PAD0_REG + pad * 4;
20.     WRITE_PERI_REG(rtc_tio_reg, (READ_PERI_REG(rtc_tio_reg)
21.                       & ~(RTC_IO_TOUCH_PAD0_DAC_M))
22.                       | (7 << RTC_IO_TOUCH_PAD0_DAC_S)//Touch Set Slope
23.                       | RTC_IO_TOUCH_PAD0_TIE_OPT_M   //Enable Tie,Init Level
24.                       | RTC_IO_TOUCH_PAD0_START_M     //Enable Touch Pad IO
25.                       | RTC_IO_TOUCH_PAD0_XPD_M);     //Enable Touch Pad Power on
27.     //force oneTime test start
28.     SET_PERI_REG_MASK(SENS_SAR_TOUCH_CTRL2_REG, SENS_TOUCH_START_EN_M|SENS_TOUCH_START_FORCE_M);
29.     SET_PERI_REG_BITS(SENS_SAR_TOUCH_CTRL1_REG, SENS_TOUCH_XPD_WAIT, 10, SENS_TOUCH_XPD_WAIT_S);
31.     while (GET_PERI_REG_MASK(SENS_SAR_TOUCH_CTRL2_REG, SENS_TOUCH_MEAS_DONE) == 0) {};
33.     uint16_t touch_value = READ_PERI_REG(SENS_SAR_TOUCH_OUT1_REG + (pad / 2) * 4) >> ((pad & 1) ? SENS_TOUCH_MEAS_OUT1_S :SENS_TOUCH_MEAS_OUT0_S);
35.     //clear touch force ,select the Touch mode is Timer
36.     CLEAR_PERI_REG_MASK(SENS_SAR_TOUCH_CTRL2_REG, SENS_TOUCH_START_EN_M|SENS_TOUCH_START_FORCE_M);
38.     //restore previous value
39.     WRITE_PERI_REG(SENS_SAR_TOUCH_ENABLE_REG, v0);
40.     return touch_value;
41. }

Kolejna funkcja to touchSetCycles:

1. void __touchSetCycles(uint16_t measure, uint16_t sleep)
2. {
3.     __touchSleepCycles = sleep;
4.     __touchMeasureCycles = measure;
5.     //Touch pad SleepCycle Time
6.     SET_PERI_REG_BITS(SENS_SAR_TOUCH_CTRL2_REG, SENS_TOUCH_SLEEP_CYCLES, __touchSleepCycles, SENS_TOUCH_SLEEP_CYCLES_S);
7.     //Touch Pad Measure Time
8.     SET_PERI_REG_BITS(SENS_SAR_TOUCH_CTRL1_REG, SENS_TOUCH_MEAS_DELAY, __touchMeasureCycles, SENS_TOUCH_MEAS_DELAY_S);
9. }

Ustawia ona odpowiednie wartości w polach kontrolnych interfejsu dotykowego.

Pierwszy parametr measure określa co jaki czas będzie wykonywany pomiar. Domyślnie ustawiona jest wartość 0x1000. Po jej zwiększeniu dłużej będzie przebiegała procedura obliczania wartości, co spowoduje otrzymaniem większych wyników i odwrotnie w przypadku jej zaniżenia. Drugi parametr określa ilość cykli uśpienia dla licznika. 

Następna funkcja przypisuje przerwanie do podanego pinu dotykowego:

1. void __touchAttachInterrupt(uint8_t pin, void (*userFunc)(void), uint16_t threshold)
2. {
3.     int8_t pad = digitalPinToTouchChannel(pin);
4.     if(pad < 0){
5.         return;
6.     }
8.     pinMode(pin, ANALOG);
10.     __touchInit();
12.     __touchInterruptHandlers[pad] = userFunc;
14.     //clear touch force ,select the Touch mode is Timer
15.     CLEAR_PERI_REG_MASK(SENS_SAR_TOUCH_CTRL2_REG, SENS_TOUCH_START_EN_M|SENS_TOUCH_START_FORCE_M);
17.     //interrupt when touch value < threshold
18.     CLEAR_PERI_REG_MASK(SENS_SAR_TOUCH_CTRL1_REG, SENS_TOUCH_OUT_SEL);
19.     //Intr will give ,when SET0 < threshold
20.     SET_PERI_REG_MASK(SENS_SAR_TOUCH_CTRL1_REG, SENS_TOUCH_OUT_1EN);
21.     //Enable Rtc Touch Module Intr,the Interrupt need Rtc out  Enable
22.     SET_PERI_REG_MASK(RTC_CNTL_INT_ENA_REG, RTC_CNTL_TOUCH_INT_ENA);
24.     //set threshold
25.     uint8_t shift = (pad & 1) ? SENS_TOUCH_OUT_TH1_S : SENS_TOUCH_OUT_TH0_S;
26.     SET_PERI_REG_BITS((SENS_SAR_TOUCH_THRES1_REG + (pad / 2) * 4), SENS_TOUCH_OUT_TH0, threshold, shift);
28.     uint32_t rtc_tio_reg = RTC_IO_TOUCH_PAD0_REG + pad * 4;
29.     WRITE_PERI_REG(rtc_tio_reg, (READ_PERI_REG(rtc_tio_reg)
30.                       & ~(RTC_IO_TOUCH_PAD0_DAC_M))
31.                       | (7 << RTC_IO_TOUCH_PAD0_DAC_S)//Touch Set Slope
32.                       | RTC_IO_TOUCH_PAD0_TIE_OPT_M   //Enable Tie,Init Level
33.                       | RTC_IO_TOUCH_PAD0_START_M     //Enable Touch Pad IO
34.                       | RTC_IO_TOUCH_PAD0_XPD_M);     //Enable Touch Pad Power on
36.     //Enable Digital rtc control :work mode and out mode
37.     SET_PERI_REG_MASK(SENS_SAR_TOUCH_ENABLE_REG,
38.                       (1 << (pad + SENS_TOUCH_PAD_WORKEN_S)) | \
39.                       (1 << (pad + SENS_TOUCH_PAD_OUTEN2_S)) | \
40.                       (1 << (pad + SENS_TOUCH_PAD_OUTEN1_S)));
41. }

W jej wywołaniu należy zdefiniować pin wywołujący dane przerwanie, funkcję obsługującą oraz maksymalną wartość jaka może spowodować wywołanie przerwania.

Program:

Najprostszy program pozwalający na obsługę pinu dotykowego wygląda następująco:

W nim oprócz standardowego włączenia portu szeregowego pojawia się funkcja opisana powyżej, której zadaniem jest odczytanie danych z padu dotykowego.

1. #define TOUCH_PIN_0 T0  //D4
3. void setup() {
4.   Serial.begin(115200);
5.   delay(1000);
6.   Serial.println("ESP32 Test");
7. }
9. void loop() {
10.   Serial.println(touchRead(TOUCH_PIN_0));
11.   delay(1000);
12. }

Pin można zdefiniować cyfrą np. dla portu dotykowego zero można wpisać 4 lub T0.

Przy przyłożeniu palca do pola dotykowego odczytana wartość pojemności ulega zmniejszeniu.

Ustawienie wywoływania przerwania odbywa się w następujący sposób:

1. touchAttachInterrupt(TOUCH_PIN_0, &TestFunction, 40);

Ustawienie sposobu odliczania danych oraz opóźnienia:

1. touchSetCycles(0x3000, 3000);

Drobna modyfikacja programu o opisane funkcje:

1. #define TOUCH_PIN_0 T0  //D4
3. void TestFunction()
4. {
5.     Serial.println("Inter");
6. }
8. void setup() {
9.   Serial.begin(115200);
10.   delay(1000);
11.   Serial.println("ESP32 Test");
12.   touchSetCycles(0x3000, 3000);
13.   touchAttachInterrupt(TOUCH_PIN_0, &TestFunction, 40);
14. }
16. void loop() {
17.   Serial.println(touchRead(TOUCH_PIN_0));
18.   delay(1000);
19. }

Dodatkowe materiały [1], [2].